I am working on a project that needs to do LDAP lookups, and lots of them. Some of my searches are for a single name, others are for multiple, and some allow partial matches (begin with passed string) while others don't.
A simple LDAP test for equality filter might look like this: uid=jsmith. Searching for multiple users (an OR search, so that any of them match) requires a syntax like this: (|(uid=jsmith)(uid=jdoe)(uid=bjones)). And then to allow wildcard searching you'd need to add a * after the name (or each name in the OR example).
To make all of this simpler I wrote this little UDF. You pass it the attribute to search on, the text to search for (lists are allowed), and whether or not wildcard searches are allowed. The string that is returned can be passed to <CFLDAP> as is.
<!--- Build LDAP filter, handle lists (treat as or search) --->
<cffunction name="BuildLDAPFilter" returntype="string" output="false">
<cfargument name="ldapField" type="string" required="yes">
<cfargument name="searchText" type="string" required="yes">
<cfargument name="wildcard" type="boolean" required="no" default="no">
<cfset var result="">
<cfset var i="">
<cfset var suffix="">
<!--- If wildcard, set suffix --->
<cfif ARGUMENTS.wildcard>
<cfset suffix="*">
</cfif>
<!--- Is this single or list? --->
<cfif ListLen(ARGUMENTS.searchText) IS 1>
<!--- Single, use as is --->
<cfset result="#ARGUMENTS.ldapField#=#ARGUMENTS.searchText##suffix#">
<cfelse>
<!--- Multiple, start filter string --->
<cfset result="(|">
<!--- Loop through fields --->
<cfloop list="#ARGUMENTS.searchText#" index="i">
<!--- Append field --->
<cfset result=result&"(#ARGUMENTS.ldapField#=#i##suffix#)">
</cfloop>
<!--- Wrap up filter string --->
<cfset result=result&")">
</cfif>
<cfreturn result>
</cffunction>
